Rules for integrands of the formP[x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)

1.  ∫(((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)dx

1.  ∫((((d+e x))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx

1:  ∫(1/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Rule 1.2.2.5.2.1:

∫(1/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  d ∫(1/(((d^2)-(e^2) (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx-e ∫(x/(((d^2)-(e^2) (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[1/((d_+e_.*x_)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  d*Int[1/((d^2-e^2*x^2)*Sqrt[a+b*x^2+c*x^4]),x] - e*Int[x/((d^2-e^2*x^2)*Sqrt[a+b*x^2+c*x^4]),x] /;
FreeQ[{a,b,c,d,e},x]

Int[1/((d_+e_.*x_)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  d*Int[1/((d^2-e^2*x^2)*Sqrt[a+c*x^4]),x] - e*Int[x/((d^2-e^2*x^2)*Sqrt[a+c*x^4]),x] /;
FreeQ[{a,c,d,e},x]

2:  ∫((((d+e x))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q<-1

Derivation: Algebraic expansion

Rule 1.2.2.5.2.2.2: If  c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q<-1, then

∫((((d+e x))^q)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  
(((e^3) (((d+e x))^(q+1)) (Sqrt[a+b (x^2)+c (x^4)]))/((q+1) (c (d^4)+b (d^2) (e^2)+a (e^4))))+
(1/((q+1) (c (d^4)+b (d^2) (e^2)+a (e^4))))∫((((d+e x))^(q+1))/(Sqrt[a+b (x^2)+c (x^4)])) (d (q+1) (c (d^2)+b (e^2))-e (c (d^2) (q+1)+b (e^2) (q+2)) x+c d (e^2) (q+1) (x^2)-c (e^3) (q+3) (x^3))dx

Program code:

Int[(d_+e_.*x_)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  e^3*(d+e*x)^(q+1)*Sqrt[a+b*x^2+c*x^4]/((q+1)*(c*d^4+b*d^2*e^2+a*e^4)) + 
  1/((q+1)*(c*d^4+b*d^2*e^2+a*e^4))*
    Int[(d+e*x)^(q+1)/Sqrt[a+b*x^2+c*x^4]*
      Simp[d*(q+1)*(c*d^2+b*e^2)-e*(c*d^2*(q+1)+b*e^2*(q+2))*x+c*d*e^2*(q+1)*x^2-c*e^3*(q+3)*x^3,x],x] /;
FreeQ[{a,b,c,d,e},x] && NeQ[c*d^4+b*d^2*e^2+a*e^4,0] && ILtQ[q,-1]

Int[(d_+e_.*x_)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  e^3*(d+e*x)^(q+1)*Sqrt[a+c*x^4]/((q+1)*(c*d^4+a*e^4)) + 
  c/((q+1)*(c*d^4+a*e^4))*
    Int[(d+e*x)^(q+1)/Sqrt[a+c*x^4]*Simp[d^3*(q+1)-d^2*e*(q+1)*x+d*e^2*(q+1)*x^2-e^3*(q+3)*x^3,x],x] /;
FreeQ[{a,c,d,e},x] && NeQ[c*d^4+a*e^4,0] && ILtQ[q,-1]

2:  ∫((((a+b (x^2)+c (x^4)))^p)/(d+e x))dx  when p+(1/2)∈ℤ

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Rule 1.2.2.5.1: If  p+(1/2)∈ℤ, then

∫((((a+b (x^2)+c (x^4)))^p)/(d+e x))dx  ⟶  d ∫((((a+b (x^2)+c (x^4)))^p)/((d^2)-(e^2) (x^2)))dx-e ∫((x (((a+b (x^2)+c (x^4)))^p))/((d^2)-(e^2) (x^2)))dx

Program code:

Int[(a_+b_.*x_^2+c_.*x_^4)^p_./(d_+e_.*x_),x_Symbol] :=
  d*Int[(a+b*x^2+c*x^4)^p/(d^2-e^2*x^2),x] - e*Int[x*(a+b*x^2+c*x^4)^p/(d^2-e^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && IntegerQ[p+1/2]

Int[(a_+c_.*x_^4)^p_./(d_+e_.*x_),x_Symbol] :=
  d*Int[(a+c*x^4)^p/(d^2-e^2*x^2),x] - e*Int[x*(a+c*x^4)^p/(d^2-e^2*x^2),x] /;
FreeQ[{a,c,d,e},x] && IntegerQ[p+1/2]

2:  ∫P[x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)dx  when PolynomialRemainder[P[x],d+e x,x]==0

Derivation: Algebraic simplification

Rule: If  PolynomialRemainder[P[x],d+e x,x]==0, then

∫P[x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫PolynomialQuotient[P[x],d+e x,x] (((d+e x))^(q+1)) (((a+b (x^2)+c (x^4)))^p) dx

Program code:

Int[Px_*(d_+e_.*x_)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[PolynomialQuotient[Px,d+e*x,x]*(d+e*x)^(q+1)*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,d,e,p,q},x] && PolyQ[Px,x] && EqQ[PolynomialRemainder[Px,d+e*x,x],0]

Int[Px_*(d_+e_.*x_)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[PolynomialQuotient[Px,d+e*x,x]*(d+e*x)^(q+1)*(a+c*x^4)^p,x] /;
FreeQ[{a,c,d,e,p,q},x] && PolyQ[Px,x] && EqQ[PolynomialRemainder[Px,d+e*x,x],0]

3:  ∫P[x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)dx  when PolynomialRemainder[P[x],a+b (x^2)+c (x^4),x]==0

Derivation: Algebraic simplification

Rule: If  PolynomialRemainder[P[x],a+b (x^2)+c (x^4),x]==0, then

∫P[x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫PolynomialQuotient[P[x],a+b (x^2)+c (x^4),x] (((d+e x))^q) (((a+b (x^2)+c (x^4)))^(p+1)) dx

Program code:

Int[Px_*(d_+e_.*x_)^q_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[PolynomialQuotient[Px,a+b*x^2+c*x^4,x]*(d+e*x)^q*(a+b*x^2+c*x^4)^(p+1),x] /;
FreeQ[{a,b,c,d,e,p,q},x] && PolyQ[Px,x] && EqQ[PolynomialRemainder[Px,a+b*x^2+c*x^4,x],0]

Int[Px_*(d_+e_.*x_)^q_.*(a_+c_.*x_^4)^p_.,x_Symbol] :=
  Int[PolynomialQuotient[Px,a+c*x^4,x]*(d+e*x)^q*(a+c*x^4)^(p+1),x] /;
FreeQ[{a,c,d,e,p,q},x] && PolyQ[Px,x] && EqQ[PolynomialRemainder[Px,a+c*x^4,x],0]

4.  ∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when  c (d^4)+b (d^2) (e^2)+a (e^4)≠0

1.  ∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when  c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q>0

1:  ∫(((((d+e x))^q) (A+B x+C (x^2)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q>0

Derivation: Algebraic expansion

Basis: (d+e x) (A+B x+C (x^2))==A d+(B d+A e) x+(C d+B e) (x^2)+C e (x^3)

Rule 1.2.2.5.2.2.2: If  c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q>0, then

∫(((((d+e x))^q) (A+B x+C (x^2)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ∫(((((d+e x))^(q-1)) (A d+(B d+A e) x+(C d+B e) (x^2)+C e (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  Int[(d+e*x)^(q-1)*(A*d+(B*d+A*e)*x+(C*d+B*e)*x^2+C*e*x^3)/Sqrt[a+b*x^2+c*x^4],x]] /; 
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],2] && NeQ[c*d^4+b*d^2*e^2+a*e^4,0] && GtQ[q,0]

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  Int[(d+e*x)^(q-1)*(A*d+(B*d+A*e)*x+(C*d+B*e)*x^2+C*e*x^3)/Sqrt[a+c*x^4],x]] /; 
FreeQ[{a,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],2] && NeQ[c*d^4+a*e^4,0] && GtQ[q,0]

2:  ∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q>0

Rule 1.2.2.5.2.2.2: If  c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q>0, then

∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  
((D (((d+e x))^q) (Sqrt[a+b (x^2)+c (x^4)]))/(c (q+2)))-(1/(c (q+2)))∫((((d+e x))^(q-1))/(Sqrt[a+b (x^2)+c (x^4)]))·
(a D e q-A c d (q+2)+(b d D-B c d (q+2)-A c e (q+2)) x+(b D e (q+1)-c (C d+B e) (q+2)) (x^2)-c (d D q+C e (q+2)) (x^3))dx

Program code:

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  D*(d+e*x)^q*Sqrt[a+b*x^2+c*x^4]/(c*(q+2)) - 
  1/(c*(q+2))*Int[(d+e*x)^(q-1)/Sqrt[a+b*x^2+c*x^4]*
    Simp[a*D*e*q-A*c*d*(q+2)+(b*d*D-B*c*d*(q+2)-A*c*e*(q+2))*x+
      (b*D*e*(q+1)-c*(C*d+B*e)*(q+2))*x^2-c*(d*D*q+C*e*(q+2))*x^3,x],x]] /; 
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x,3] && NeQ[c*d^4+b*d^2*e^2+a*e^4,0] && GtQ[q,0]

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  D*(d+e*x)^q*Sqrt[a+c*x^4]/(c*(q+2)) - 
  1/(c*(q+2))*Int[(d+e*x)^(q-1)/Sqrt[a+c*x^4]*
    Simp[a*D*e*q-A*c*d*(q+2)-c*(B*d*(q+2)+A*e*(q+2))*x-c*(C*d+B*e)*(q+2)*x^2-c*(d*D*q+C*e*(q+2))*x^3,x],x]] /; 
FreeQ[{a,c,d,e},x] && PolyQ[Px,x,3] && NeQ[c*d^4+a*e^4,0] && GtQ[q,0]

2:  ∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  when c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q<-1

Note: If  (d^3) D-C (d^2) e+B d (e^2)-A (e^3)==0, then PolynomialRemainder[A+B x+C (x^2)+D (x^3),d+e x,x]==0.

Rule 1.2.2.5.2.2.2: If  c (d^4)+b (d^2) (e^2)+a (e^4)≠0 ∧ q<-1, then

∫(((((d+e x))^q) (A+B x+C (x^2)+D (x^3)))/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  
-((((d^3) D-C (d^2) e+B d (e^2)-A (e^3)) (((d+e x))^(q+1)) (Sqrt[a+b (x^2)+c (x^4)]))/((q+1) (c (d^4)+b (d^2) (e^2)+a (e^4))))+(1/((q+1) (c (d^4)+b (d^2) (e^2)+a (e^4))))∫((((d+e x))^(q+1))/(Sqrt[a+b (x^2)+c (x^4)]))·
((q+1) (a e ((d^2) D-C d e+B (e^2))+A d (c (d^2)+b (e^2)))-
(e (q+1) (A c (d^2)+a e (d D-C e))-B d (c (d^2) (q+1)+b (e^2) (q+2))-b ((d^3) D-C (d^2) e-A (e^3) (q+2))) x+
(q+1) (D e (b (d^2)+a (e^2))+c d (C (d^2)-e (B d-A e))) (x^2)+
c (q+3) ((d^3) D-C (d^2) e+B d (e^2)-A (e^3)) (x^3))dx

Program code:

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  -(d^3*D-C*d^2*e+B*d*e^2-A*e^3)*(d+e*x)^(q+1)*Sqrt[a+b*x^2+c*x^4]/((q+1)*(c*d^4+b*d^2*e^2+a*e^4)) + 
  1/((q+1)*(c*d^4+b*d^2*e^2+a*e^4))*
    Int[((d+e*x)^(q+1)/Sqrt[a+b*x^2+c*x^4])*
      Simp[(q+1)*(a*e*(d^2*D-C*d*e+B*e^2)+A*d*(c*d^2+b*e^2)) - 
        (e*(q+1)*(A*c*d^2+a*e*(d*D-C*e))-B*d*(c*d^2*(q+1)+b*e^2*(q+2))-b*(d^3*D-C*d^2*e-A*e^3*(q+2)))*x + 
        (q+1)*(D*e*(b*d^2+a*e^2)+c*d*(C*d^2-e*(B*d-A*e)))*x^2 + 
        c*(q+3)*(d^3*D-C*d^2*e+B*d*e^2-A*e^3)*x^3,x],x]] /; 
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],3] && NeQ[c*d^4+b*d^2*e^2+a*e^4,0] && LtQ[q,-1]

Int[Px_*(d_+e_.*x_)^q_/Sqrt[a_+c_.*x_^4],x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  -(d^3*D-C*d^2*e+B*d*e^2-A*e^3)*(d+e*x)^(q+1)*Sqrt[a+c*x^4]/((q+1)*(c*d^4+a*e^4)) + 
  1/((q+1)*(c*d^4+a*e^4))*
    Int[((d+e*x)^(q+1)/Sqrt[a+c*x^4])*
      Simp[(q+1)*(a*e*(d^2*D-C*d*e+B*e^2)+A*d*(c*d^2)) - 
        (e*(q+1)*(A*c*d^2+a*e*(d*D-C*e))-B*d*(c*d^2*(q+1)))*x + 
        (q+1)*(D*e*(a*e^2)+c*d*(C*d^2-e*(B*d-A*e)))*x^2 + 
        c*(q+3)*(d^3*D-C*d^2*e+B*d*e^2-A*e^3)*x^3,x],x]] /; 
FreeQ[{a,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],3] && NeQ[c*d^4+a*e^4,0] && LtQ[q,-1]

3.  ∫((A+B x+C (x^2)+D (x^3))/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  c (d^4)+b (d^2) (e^2)+a (e^4)≠0

1:  ∫((A+B x)/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  when  B d-A e≠0 ∧ (c^2) (d^6)+a (e^4) (13 c (d^2)+b (e^2))==0 ∧ (b^2) (e^4)-12 c (d^2) (c (d^2)-b (e^2))==0 ∧ 4 A c d e+B (2 c (d^2)-b (e^2))==0

Derivation: Integration by substitution

Basis:  If  (c^2) (d^6)+a (e^4) (13 c (d^2)+b (e^2))==0 ∧ (b^2) (e^4)-12 c (d^2) (c (d^2)-b (e^2))==0 ∧ 4 A c d e+B (2 c (d^2)-b (e^2))==0, then 
		((A+B x)/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))==-(((A^2) (B d+A e))/e) Subst[(1/(6 (A^3) B d+3 (A^4) e-a e (x^2))),x,((((A+B x))^2)/(Sqrt[a+b (x^2)+c (x^4)]))] (∂_x)((((A+B x))^2)/(Sqrt[a+b (x^2)+c (x^4)]))

Rule 1.2.2.9.2.1: If  B d-A e≠0 ∧ (c^2) (d^6)+a (e^4) (13 c (d^2)+b (e^2))==0 ∧ (b^2) (e^4)-12 c (d^2) (c (d^2)-b (e^2))==0 ∧ 4 A c d e+B (2 c (d^2)-b (e^2))==0, then

∫((A+B x)/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  -(((A^2) (B d+A e))/e) Subst[∫(1/(6 (A^3) B d+3 (A^4) e-a e (x^2)))dx,x,((((A+B x))^2)/(Sqrt[a+b (x^2)+c (x^4)]))]

Program code:

Int[(A_+B_.*x_)/((d_+e_.*x_)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  -A^2*(B*d+A*e)/e*Subst[Int[1/(6*A^3*B*d+3*A^4*e-a*e*x^2),x],x,(A+B*x)^2/Sqrt[a+b*x^2+c*x^4]] /;
FreeQ[{a,b,c,d,e,A,B},x] && NeQ[B*d-A*e,0] && EqQ[c^2*d^6+a*e^4*(13*c*d^2+b*e^2),0] && 
  EqQ[b^2*e^4-12*c*d^2*(c*d^2-b*e^2),0] && EqQ[4*A*c*d*e+B*(2*c*d^2-b*e^2),0]

2:  ∫((A+B x+C (x^2)+D (x^3))/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  when c (d^4)+b (d^2) (e^2)+a (e^4)≠0

Derivation: Algebraic expansion

Basis: ((A+B x+C (x^2)+D (x^3))/(d+e x))==((x (B d-A e+(d D-C e) (x^2)))/((d^2)-(e^2) (x^2)))+((A d+(C d-B e) (x^2)-D e (x^4))/((d^2)-(e^2) (x^2)))

Rule 1.2.2.5.2.2.2: If  c (d^4)+b (d^2) (e^2)+a (e^4)≠0, then

∫((A+B x+C (x^2)+D (x^3))/((d+e x) (Sqrt[a+b (x^2)+c (x^4)])))dx  ⟶  ∫((x (B d-A e+(d D-C e) (x^2)))/(((d^2)-(e^2) (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx+∫((A d+(C d-B e) (x^2)-D e (x^4))/(((d^2)-(e^2) (x^2)) (Sqrt[a+b (x^2)+c (x^4)])))dx

Program code:

Int[Px_/((d_+e_.*x_)*Sqrt[a_+b_.*x_^2+c_.*x_^4]),x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  Int[(x*(B*d-A*e+(d*D-C*e)*x^2))/((d^2-e^2*x^2)*Sqrt[a+b*x^2+c*x^4]),x] + 
  Int[(A*d+(C*d-B*e)*x^2-D*e*x^4)/((d^2-e^2*x^2)*Sqrt[a+b*x^2+c*x^4]),x]] /; 
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],3] && NeQ[c*d^4+b*d^2*e^2+a*e^4,0]

Int[Px_/((d_+e_.*x_)*Sqrt[a_+c_.*x_^4]),x_Symbol] :=
  With[{A=Coeff[Px,x,0],B=Coeff[Px,x,1],C=Coeff[Px,x,2],D=Coeff[Px,x,3]},
  Int[(x*(B*d-A*e+(d*D-C*e)*x^2))/((d^2-e^2*x^2)*Sqrt[a+c*x^4]),x] + 
  Int[(A*d+(C*d-B*e)*x^2-D*e*x^4)/((d^2-e^2*x^2)*Sqrt[a+c*x^4]),x]] /; 
FreeQ[{a,c,d,e},x] && PolyQ[Px,x] && LeQ[Expon[Px,x],3] && NeQ[c*d^4+a*e^4,0]

5:  ∫((P[x] (((a+b (x^2)+c (x^4)))^p))/(d+e x))dx  when p+(1/2)∈ℤ

Derivation: Algebraic expansion

Basis: (1/(d+e x))==(d/((d^2)-(e^2) (x^2)))-((e x)/((d^2)-(e^2) (x^2)))

Rule 1.2.2.9.1: If  p+(1/2)∈ℤ, then

∫((P[x] (((a+b (x^2)+c (x^4)))^p))/(d+e x))dx  ⟶  d ∫((P[x] (((a+b (x^2)+c (x^4)))^p))/((d^2)-(e^2) (x^2)))dx-e ∫((x P[x] (((a+b (x^2)+c (x^4)))^p))/((d^2)-(e^2) (x^2)))dx

Program code:

Int[Px_*(a_+b_.*x_^2+c_.*x_^4)^p_./(d_+e_.*x_),x_Symbol] :=
  d*Int[Px*(a+b*x^2+c*x^4)^p/(d^2-e^2*x^2),x] - e*Int[x*Px*(a+b*x^2+c*x^4)^p/(d^2-e^2*x^2),x] /;
FreeQ[{a,b,c,d,e},x] && PolyQ[Px,x] && IntegerQ[p+1/2]

Int[Px_*(a_+c_.*x_^4)^p_./(d_+e_.*x_),x_Symbol] :=
  d*Int[Px*(a+c*x^4)^p/(d^2-e^2*x^2),x] - e*Int[x*Px*(a+c*x^4)^p/(d^2-e^2*x^2),x] /;
FreeQ[{a,c,d,e},x] && PolyQ[Px,x] && IntegerQ[p+1/2]